KOIN_API_V2/build.gradle at develop · BCSDLab/KOIN_API_V2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.1.5'
    id 'io.spring.dependency-management' version '1.1.3'
}

springBoot {
    mainClass = 'in.koreatech.koin.KoinApplication'
}

group = 'in.koreatech'

java {
    sourceCompatibility = '17'
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    // spring boot starters
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation 'org.springframework.boot:spring-boot-starter-data-mongodb'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-websocket'
    implementation 'org.springframework.boot:spring-boot-starter-webflux'
    implementation 'org.springframework.boot:spring-boot-starter-aop'

    // db
    runtimeOnly 'com.mysql:mysql-connector-j'
    implementation 'org.flywaydb:flyway-mysql'

    // security
    implementation 'org.springframework.security:spring-security-crypto:6.2.2'
    implementation 'io.jsonwebtoken:jjwt-api:0.12.3'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.3'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.3'

    // infra (aws, cloud, fcm)
    implementation platform('software.amazon.awssdk:bom:2.20.56')
    implementation 'software.amazon.awssdk:s3'
    implementation 'software.amazon.awssdk:ses'
    implementation 'software.amazon.awssdk:cloudfront'
    implementation 'com.google.firebase:firebase-admin:9.2.0'
    implementation 'org.redisson:redisson-spring-boot-starter:3.35.0'

    // observability & notification
    implementation 'net.logstash.logback:logstash-logback-encoder:8.0'
    implementation 'com.github.maricn:logback-slack-appender:1.4.0'

    // resilience & retry
    implementation 'io.github.resilience4j:resilience4j-spring-boot3:2.1.0'
    implementation 'org.springframework.retry:spring-retry'

    // utils
    implementation 'org.jsoup:jsoup:1.15.3'
    implementation 'com.google.code.gson:gson:2.10.1'
    implementation group: 'org.json', name: 'json', version: '20231013'
    implementation 'com.github.ua-parser:uap-java:1.4.4'
    implementation 'org.apache.poi:poi-ooxml:5.2.5'
    implementation 'net.lingala.zip4j:zip4j:2.6.1'
    implementation 'com.github.f4b6a3:tsid-creator:5.2.6'

    // querydsl
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // swagger
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.3.0'

    // lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // test
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.testcontainers:testcontainers:1.21.4'
    testImplementation 'org.testcontainers:junit-jupiter:1.19.3'
    testImplementation 'org.testcontainers:mysql'
    testImplementation 'org.testcontainers:localstack'
}

clean {
    delete file('src/main/generated')
}

tasks.named('bootBuildImage') {
    builder = 'paketobuildpacks/builder-jammy-base:latest'
}

tasks.named('test') {
    maxHeapSize = '2g'
    useJUnitPlatform {
        excludeTags 'web-auth-http'
    }
}

// 실제 HTTP 서버는 별도 JVM에서 실행해 기존 테스트의 Spring 컨텍스트 캐시와 분리한다.
tasks.register('webAuthHttpTest', Test) {
    description = '웹 쿠키 인증의 실제 HTTP 흐름을 검증합니다.'
    group = 'verification'
    testClassesDirs = sourceSets.test.output.classesDirs
    classpath = sourceSets.test.runtimeClasspath
    useJUnitPlatform {
        includeTags 'web-auth-http'
    }
    shouldRunAfter tasks.named('test')
}

tasks.named('check') {
    dependsOn tasks.named('webAuthHttpTest')
}