bootit/flake.nix at main · mincomk/bootit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
{
  description = "bootit: a lightweight next-boot selector";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs =
    { self, nixpkgs }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});

      version = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package.version;
    in
    {
      packages = forAllSystems (pkgs: rec {
        bootit = pkgs.rustPlatform.buildRustPackage {
          pname = "bootit";
          inherit version;
          src = ./.;

          cargoLock.lockFile = ./Cargo.lock;

          # `it` is a second bin in the same crate; buildRustPackage installs
          # every bin, so both `bootit` and `it` land in $out/bin.
          meta = {
            description = "Lightweight next-boot selector";
            homepage = "https://github.com/mincomk/bootit";
            license = pkgs.lib.licenses.mit;
            mainProgram = "bootit";
            platforms = pkgs.lib.platforms.linux;
          };
        };

        default = bootit;
      });

      apps = forAllSystems (pkgs: {
        default = {
          type = "app";
          program = "${self.packages.${pkgs.stdenv.hostPlatform.system}.bootit}/bin/bootit";
          meta.description = "Run bootit without installing it";
        };
      });

      checks = forAllSystems (pkgs: {
        bootit = self.packages.${pkgs.stdenv.hostPlatform.system}.bootit;
      });

      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = [
            pkgs.cargo
            pkgs.rustc
            pkgs.rustfmt
            pkgs.clippy
            pkgs.rust-analyzer
          ];
        };
      });
    };
}